Ultimate Brain

https://thomasjfrank.com/docs/ultimate-brain
Admin
Ultimate Brain is a comprehensive Notion template designed to organize your entire life by...
Tokens:48,752
Snippets:629
Trust Score:9.8
Update:3 months ago
Show doc for...
Tokens:
Raw
### Configure Start Button Session Name Formula

Source: https://thomasjfrank.com/docs/ultimate-brain/how-to-add-time-tracking-to-ultimate-brain

Used within the Start button automation to generate a unique session name based on the task name and session count.

```javascript
let(
  sessionNumber,
  This Page.Sessions.length() + 1,
  This Page + " (Session " + sessionNumber + ")"
)
```

--------------------------------

### Get Project Quarter

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/projects

Returns the quarter of the year for the project's Target Deadline.

```javascript
prop("Target Deadline").formatDate("Q")
```

--------------------------------

### Calculate Duration in Minutes

Source: https://thomasjfrank.com/docs/ultimate-brain/how-to-add-time-tracking-to-ultimate-brain

Use this formula to calculate the difference between Start and End date properties in minutes.

```javascript
dateBetween(
	prop("End"),
	prop("Start"),
	"minutes"
) + " minute(s)"
```

--------------------------------

### Construct Date Range

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/work-sessions

Creates a date range object from the Start and End properties for use in calendar views.

```javascript
dateRange(
  prop("Start"),
  prop("End")
)
```

--------------------------------

### Format Total Time Card

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/recipes

Calculates total time from prep and cook properties and formats it as a styled string.

```javascript
lets(
	totalTimeRaw,
	prop("Cook Time") + prop("Prep Time"),
	hours,
	floor(totalTimeRaw / 60),
	minutes,
	totalTimeRaw % 60,
	hourPlurality,
	if(
		hours == 1,
		"",
		"s"
	),
	minutePlurality,
	if(
		minutes == 1,
		"",
		"s"
	),
	time,
	ifs(
		totalTimeRaw > 60,
		hours + " hr" + hourPlurality + ", " + minutes + " minute" + minutePlurality,
		totalTimeRaw == 60,
		hours + " hr",
		minutes + " min" + minutePlurality
	),
	time.style(
		"c",
		"b",
		"green",
		"green_background"
	)
)
```

--------------------------------

### Configure Localization and Recur Unit Options

Source: https://thomasjfrank.com/docs/ultimate-brain/changelog

Use this array structure to define localized names for weekdays, recurrence units, and status options. Ensure these match the values configured in your database properties.

```javascript
[
/* Rewrite these weekday and recur unit options in your own language, so your second brain can work even better with your first. Make sure to set up the same options in the "Recur Unit" and "Days" properties afterward, so you can select them. Feel free to remove the original names afterward! */

/* ["lunes", "3ª", "mercredi", "木曜日", "piątek", "lørdag", "Double Sunday"] */
["Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday", "Sunday"],

/* ["Day(s)", "Week(s)", "Month(s)", "Year(s)", "Month(s) on the Last Day", "Month(s) on the First Weekday", "Month(s) on the Last Weekday", "Nth Weekday of Month"] */
["Day(s)", "Week(s)", "Month(s)", "Year(s)", "Month(s) on the Last Day", "Month(s) on the First Weekday", "Month(s) on the Last Weekday", "Nth Weekday of Month"],

/* This final list is for Status option names. */
["To Do", "Doing", "Done"]
]
```

--------------------------------

### Calculate Pages Read

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/reading-log

Computes the total pages read in a session by subtracting the start page from the end page.

```javascript
if(
	not empty(prop("Start Page")) && not empty(prop("End Page")),
	prop("End Page") - prop("Start Page"),
	0
)
```

--------------------------------

### Define Localization Keys Formula

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/projects

Maps project status options to translated terms and categorizes them into active or inactive groups for filtering.

```javascript
/* If you would like to translate your Status option names, translate them in the Status property AND in this formula as well. Below, you'll see variables for each of the important Status options in Ultimate Brain. For each, you can replace the terms in quotes ("") with translated terms. The final argument (the List defined by the brackets) is the return value of this formula. It is a multi-dimensional List (e.g. array), where the most important element is the 2nd (index 1) of the top List. This sub-List contains all of the Status options that are considered Active.

Since Notion formulas don't let us access the Groups of Status properties (e.g. To Do, In Progress, Complete), this is the best way to get the Group of a translated (or added) Status option.

If you have added extra options that are considered Active, add them as strings between the brackets underneath the additionalActiveStatusOptions variable. This can be helpful if you want to define multiple stages for Active projects.

Example: ["Design", "Development", "QA"] */

lets(
	planned,
	/* Edit the term below this line to translated the Planned status. E.g. "Zaplanowany" */
	"Planned",
	onHold,
	/* Edit the term below this line to translated the On Hold status. "Zastopowany" */
	"On Hold",
	doing,
	/* Edit the term below this line to translated the Doing status. "W trakcie" */
	"Doing",
	ongoing,
	/* Edit the term below this line to translated the Ongoing status. "Otwarty" */
	"Ongoing",
	done,
	/* Edit the term below this line to translated the Done status. "Zakończony" */
	"Done",
	additionalActiveStatusOptions,
	/* If you would like to add additional Active status options, add them as strings between these brackets. See the comment above for an example. */
	[],
	/* Do not edit anything below this line */
	[
		[planned, onHold],
		[doing, ongoing, additionalActiveStatusOptions].flat(),
		[done]
	]
)
```

--------------------------------

### Calculate Duration in Minutes

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/work-sessions

Computes the session length in minutes by calculating the difference between the Start and End properties, defaulting to the current time if the session is ongoing.

```javascript
let(
  duration,
  if(
    empty(prop("End")),
    dateBetween(now(), prop("Start"), "minutes"),
    dateBetween(prop("End"), prop("Start"), "minutes")
  ),
  duration >= 0 ? duration : 0
)
```

--------------------------------

### Calculate Estimated Meal Time Formula

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/meal-planner

Calculates the total preparation time based on recipe data or an override value, returning a styled string badge.

```javascript
lets(
		totalTimeRaw,
		if(
			!empty(prop("Time Override")),
			prop("Time Override"),
			prop("Recipes").map(current.prop("Total Time")).max()
		),
		hours,
		floor(totalTimeRaw / 60),
		minutes,
		totalTimeRaw % 60,
	hourPlurality,
		if(
			hours == 1,
			"",
			"s"
		),
		minutePlurality,
		if(
			minutes == 1,
			"",
			"s"
		),
		time,
		ifs(
			totalTimeRaw > 60,
			hours + " hr" + hourPlurality + ", " + minutes + " minute" + minutePlurality,
			totalTimeRaw == 60,
			hours + " hr",
			minutes + " min" + minutePlurality
		),
		badgeColor,
		ifs(
			totalTimeRaw >= 90, "red",
			totalTimeRaw >= 45, "yellow",
			"green"
		),
		time.style(
			"c",
			"b",
			badgeColor,
			badgeColor + "_background"
		)
	)
```

--------------------------------

### Time Tracking Session Formulas

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/tasks

Formulas for handling time tracking session variables and naming conventions.

```javascript
context("Trigger page").prop("Sessions")
```

```javascript
context("Page added") + " (Session)"
```

--------------------------------

### Calculate Quick Recipe Status

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/recipes

Determines if a recipe is considered 'Quick' based on a 45-minute threshold.

```javascript
prop("Total Time") <= 45
```

--------------------------------

### Format Name as Last, First

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/people

Formula to reorder names into Last, First format, handling suffixes and custom surnames.

```javascript
ifs(
	prop("Full Name").empty(),
	"",
	prop("Surname"),
	prop("Surname") + ", " + prop("Full Name").format().replace(
		prop("Surname").format() + "$",
		""
	),
	lets(
		suffixes,
		["Jr.", "Sr.", "II", "III", "IV", "V", "MD", "PhD", "DDS", "Esq.", "OBE", "QC"],
		parts,
		prop("Full Name").split(" "),
		suffixFlag,
		if(
			suffixes.includes(parts.last()),
			true,
			false
		),
		if(
			parts.length() == 1,
			prop("Full Name"),
			if(
				suffixFlag,
				parts.at(parts.length() - 2) + ", " + parts.slice(0, parts.length() - 2).join(" ") + " " + parts.last(),
				parts.last() + ", " + parts.slice(0, parts.length() - 1).join(" ")
			)
		)
	)
)
```

--------------------------------

### Calculate Recipe Count Formula

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/recipe-tags

Calculates the number of related recipes and formats the output with a styled string.

```javascript
lets(
	recipeCount,
	prop("Recipes").length(),
	plurality,
	if(
		recipeCount == 1,
		"",
		"s"
	),
	(
		recipeCount.format() +
		" recipe" +
		plurality
	).style(
		"c", "b", "blue", "blue_background"
	)
)
```

--------------------------------

### Perform Robust Comparison Using Localization Key

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/tasks

Checks a property against both a hard-coded string and a value retrieved from the Localization Key array to support localization.

```javascript
if(
  prop("Recur Unit") == "Days(s)" or prop("Recur Unit") == prop("Localization Key").at(1).at(0), true, false
)
```

--------------------------------

### Calculate Task Meta Summary Formula

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/projects

Displays a count of active and overdue tasks related to the project, styled by status.

```javascript
lets(
	active,
	prop("Tasks")
		.filter(
			current.prop("Status") != "Done" and current.prop("Status") != current.prop("Localization Key").at(2).last()
		)
		.length(),
	overdue,
	prop("Tasks")
		.filter(
			current.prop("Status") != "Done" and current.prop("Status") != current.prop("Localization Key").at(2).last()
			and now().dateBetween(current.prop("Due"), "days") > 0
		)
		.length(),
	ifs(
		prop("Tasks").length() == 0,
		"No Tasks Created".style("blue"),
		active == 0,
		"All Tasks Done".style("green"),
		if(
			overdue == 0,
			(active + " Active").style("blue"),
			(active.style("b") + " Active - ").style("blue") 
			+ (overdue.style("b") + " Overdue").style("red")
		)
	)
)
```

--------------------------------

### Display My Day Label

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/tasks

Generates a static label for the My Day page interface.

```javascript
let(
  showLabel,
  true,
  if(
    showLabel,
    "My Day",
    ""
  )
)
```

--------------------------------

### Display Active Tag Projects Formula

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/tags

Shows a styled label indicating the number of active projects associated with the tag.

```javascript
lets(
	count,
	prop("Projects").filter(current.prop("Status") == "Doing" or current.prop("Status") == "Ongoing").length(),
	ifs(
		count > 0,
		(
			count + " Active Project" + ifs(count != 1, "s")
		).style("b","c","green","green_background")
	)
)
```

--------------------------------

### Calculate Total Time

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/recipes

Sums the prep and cook time properties to provide a numeric value for sorting.

```javascript
prop("Cook Time") + prop("Prep Time")
```

--------------------------------

### Sub-Task Arrow

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/tasks

Formula to indent sub-tasks in List views by prepending an arrow.

```javascript
ifs(
  prop("Parent Task"), 
  "→"
)
```

--------------------------------

### Next Due Calculation Logic

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/tasks

Logic for calculating the next due date based on recurrence units like months on the last day or specific weekday intervals.

```javascript
            recurUnit == "monthsonthelastday",
              if(
                dateNow >= lastDayBaseDate,
                nextLastBaseDate,
                lastDayBaseDate
              ),
            
            recurUnit == "monthsonthefirstweekday",
              if(
                dateNow >= firstWeekdayBaseDate,
                nextFirstWeekday,
                firstWeekdayBaseDate
              ),
            
            recurUnit == "monthsonthelastweekday",
              if(
                dateNow >= lastWeekdayBaseDate,
                nextLastWeekday,
                lastWeekdayBaseDate
              ),
            
            includes(["days", "weeks", "months", "years"], recurUnit), 
              if(
                dateBetween(dateNow, dateDue, "days") >= 1,
                if(
                  recurUnitLapseLength == ceil(recurUnitLapseLength),
                  dateAdd(dateDue, (recurUnitLapseLength + 1) * recurIntervalProp, recurUnit),
                  dateAdd(dateDue, ceil(recurUnitLapseLength) * recurIntervalProp, recurUnit)
                ),
                dateAdd(dateDue, recurIntervalProp, recurUnit)
              ),

            emptyDate
          ),
        
        recurRange, dateBetween(nextDueStart, dateDue, "days"),
        
        timeNextDueStart, dateAdd(dateStart(dueProp), recurRange, "days"),
        
        timeNextDueEnd, dateAdd(dateEnd(dueProp), recurRange, "days"),
        
        nextDue,
          if(
            hasRange,
            dateRange(timeNextDueStart, timeNextDueEnd),
            timeNextDueStart
          ),
        
        nextDue
      ),
      dueProp
    ),
    emptyDate
  )
)
```

```javascript
lets(
  dueProp, prop("Due"),
  
  recurIntervalProp, prop("Recur Interval"),
  
  recurUnitProp, prop("Recur Unit"),
  
  localizationKeyProp, prop("Localization Key"),
  
  emptyDate, parseDate(""),
  
  if(!empty(recurIntervalProp) and !empty(dueProp),
    if(recurIntervalProp > 0 and recurIntervalProp == ceil(recurIntervalProp),
      lets(
        recurUnit,
          ifs(
            or(recurUnitProp == at(at(localizationKeyProp, 1), 0), recurUnitProp == "Day(s)"), "days",
            or(recurUnitProp == at(at(localizationKeyProp, 1), 1), recurUnitProp == "Week(s)"), "weeks",
            or(recurUnitProp == at(at(localizationKeyProp, 1), 2), recurUnitProp == "Month(s)"), "months",
            or(recurUnitProp == at(at(localizationKeyProp, 1), 3), recurUnitProp == "Year(s)"), "years",
            or(recurUnitProp == at(at(localizationKeyProp, 1), 4), recurUnitProp == "Month(s) on the Last Day"), "monthsonthelastday",
            or(recurUnitProp == at(at(localizationKeyProp, 1), 5), recurUnitProp == "Month(s) on the First Weekday"), "monthsonthefirstweekday",
            or(recurUnitProp == at(at(localizationKeyProp, 1), 6), recurUnitProp == "Month(s) on the Last Weekday"), "monthsonthelastweekday",
            "days"
          ),
        
        weekdays,
          match(
            [
              if(or(includes(prop("Days (Only if Set to 1 Day(s))"), at(at(localizationKeyProp, 0), 1 - 1)), includes(prop("Days (Only if Set to 1 Day(s))"), "Monday")), 1, false),
              if(or(includes(prop("Days (Only if Set to 1 Day(s))"), at(at(localizationKeyProp, 0), 2 - 1)), includes(prop("Days (Only if Set to 1 Day(s))"), "Tuesday")), 2, false),
              if(or(includes(prop("Days (Only if Set to 1 Day(s))"), at(at(localizationKeyProp, 0), 3 - 1)), includes(prop("Days (Only if Set to 1 Day(s))"), "Wednesday")), 3, false),
              if(or(includes(prop("Days (Only if Set to 1 Day(s))"), at(at(localizationKeyProp, 0), 4 - 1)), includes(prop("Days (Only if Set to 1 Day(s))"), "Thursday")), 4, false),
              if(or(includes(prop("Days (Only if Set to 1 Day(s))"), at(at(localizationKeyProp, 0), 5 - 1)), includes(prop("Days (Only if Set to 1 Day(s))"), "Friday")), 5, false),
              if(or(includes(prop("Days (Only if Set to 1 Day(s))"), at(at(localizationKeyProp, 0), 6 - 1)), includes(prop("Days (Only if Set to 1 Day(s))"), "Saturday")), 6, false),
              if(or(includes(prop("Days (Only if Set to 1 Day(s))"), at(at(localizationKeyProp, 0), 7 - 1)), includes(prop("Days (Only if Set to 1 Day(s))"), "Sunday")), 7, false)
            ],
            "[1-7]"
          ),
        
        dateDue, parseDate(formatDate(dueProp, "YYYY-MM-DD")),
        
        timeNow, now(),
        
        dateNow, parseDate(formatDate(timeNow, "YYYY-MM-DD")),
        
        hasRange, dateEnd(dueProp) > dateStart(dueProp),
        
        recurUnitLapseLength,
          if(
            includes(["days", "weeks", "months", "years"], recurUnit),
            dateBetween(dateNow, dateDue, recurUnit) / recurIntervalProp,
```

--------------------------------

### Calculate Project Active Status (Base Version)

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/tasks

Determines if a task's project is active based on status or localization keys in the base Ultimate Brain template.

```javascript
lets(
  project,
  if(
    prop("Parent Task"),
    prop("Parent Task").first().prop("Project").first(),
    prop("Project").first()
  ),
  projectStatus,
  project.prop("Status"),
  projectLocalizationKey,
  project.prop("Localization Key"),
  if(
    projectStatus == "Doing" 
    or projectStatus == "Ongoing"
    or projectLocalizationKey.at(1).includes(projectStatus),
    true,
    false
  )
)
```

--------------------------------

### Calculate Numeric Estimated Time Formula

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/meal-planner

Returns the raw numeric value for estimated preparation time, used primarily for sorting purposes.

```javascript
if(
	!empty(prop("Time Override")),
	prop("Time Override"),
	prop("Recipes").map(current.prop("Total Time")).max()
)
```

--------------------------------

### Extract URL Base Domain

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/recipes

Parses the base domain from a full URL string.

```javascript
prop("URL")
	.replace("[^]*//", "")
	.split("/")
	.first()
```

--------------------------------

### Display URL Icon Formula

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/notes

Displays a clickable link icon if a URL property is present. Used for quick access in condensed list views.

```javascript
if(
	empty(prop("URL")),
	"",
	"🔗".style("c", "gray_background").link(prop("URL"))
)
```

--------------------------------

### Calculate Project Progress

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/projects

Calculates the percentage of completed tasks related to the project.

```javascript
if(
	prop("Tasks").empty(),
	"".toNumber(),
	(prop("Tasks")
	.filter(
		current.prop("Status") == "Done" or current.prop("Status") == current.prop("Localization Key").at(2).last()
	)
	.length()
/ prop("Tasks")
	.length()
	* 1000)
.round() 
/ 1000
)
```

--------------------------------

### Calculate Next Due Date Logic

Source: https://thomasjfrank.com/docs/ultimate-brain/databases/tasks

Formulas for determining base dates and next due dates for recurring tasks in Notion.

```Notion Formula
dateSubtract(dateAdd(dateSubtract(dateAdd(dateDue, ceil((year(conditionalDateNow) * 12 + month(conditionalDateNow) - (year(dateDue) * 12 + month(dateDue))) / recurIntervalProp) * recurIntervalProp, "months"), date(dateAdd(dateDue, ceil((year(conditionalDateNow) * 12 + month(conditionalDateNow) - (year(dateDue) * 12 + month(dateDue))) / recurIntervalProp) * recurIntervalProp, "months")) - 1, "days"), 1, "months"), 1, "days"),
                  dateSubtract(dateAdd(dateSubtract(dateAdd(dateDue, recurIntervalProp, "months"), date(dateAdd(dateDue, recurIntervalProp, "months")) - 1, "days"), 1, "months"), 1, "days")
                ),
                false
              ),
            
            firstDayBaseDate,
              if(
                lastDayBaseDate != false,
                dateSubtract(lastDayBaseDate, date(lastDayBaseDate) - 1, "days"),
                false
              ),
            
            firstWeekdayBaseDate,
              if(
                lastDayBaseDate != false,
                if(
                  test(day(firstDayBaseDate), "6|7"), 
                  dateAdd(firstDayBaseDate, 8 - day(firstDayBaseDate), "days"),
                  firstDayBaseDate
                ),
                false
              ),
            
            lastWeekdayBaseDate,
              if(
                lastDayBaseDate != false,
                if(
                  test(day(lastDayBaseDate), "6|7"), 
                  dateSubtract(lastDayBaseDate, day(lastDayBaseDate) - 5, "days"),
                  lastDayBaseDate
                ),
                false
              ),
            
            nextLastBaseDate,
              if(
                lastDayBaseDate != false,
                dateSubtract(dateAdd(dateSubtract(dateAdd(lastDayBaseDate, recurIntervalProp, "months"), date(dateAdd(lastDayBaseDate, recurIntervalProp, "months")) - 1, "days"), 1, "months"), 1, "days"),
                false
              ),
            
            nextFirstBaseDate,
              if(
                lastDayBaseDate != false,
                dateSubtract(nextLastBaseDate, date(nextLastBaseDate) - 1, "days"),
                false
              ),
            
            nextFirstWeekday,
              if(
                lastDayBaseDate != false,
                if(
                  test(day(nextFirstBaseDate), "6|7"), 
                  dateAdd(nextFirstBaseDate, 8 - day(nextFirstBaseDate), "days"),
                  nextFirstBaseDate
                ),
                false
              ),
            
            nextLastWeekday,
              if(
                lastDayBaseDate != false,
                if(
                  test(day(nextLastBaseDate), "6|7"), 
                  dateSubtract(nextLastBaseDate, day(nextLastBaseDate) - 5, "days"),
                  nextLastBaseDate
                ),
                false
              ),
            
            nextDueStart,
              ifs(
                recurUnit == "days" and length(weekdays) > 0 and recurIntervalProp == 1,
                  if(
                    conditionalDateNow >= dateDue,
                    ifs(
                      includes(weekdays, format(day(dateAdd(conditionalDateNow, 1, "days")))), dateAdd(conditionalDateNow, 1, "days"),
                      includes(weekdays, format(day(dateAdd(conditionalDateNow, 2, "days")))), dateAdd(conditionalDateNow, 2, "days"),
                      includes(weekdays, format(day(dateAdd(conditionalDateNow, 3, "days")))), dateAdd(conditionalDateNow, 3, "days"),
                      includes(weekdays, format(day(dateAdd(conditionalDateNow, 4, "days")))), dateAdd(conditionalDateNow, 4, "days"),
                      includes(weekdays, format(day(dateAdd(conditionalDateNow, 5, "days")))), dateAdd(conditionalDateNow, 5, "days"),
                      includes(weekdays, format(day(dateAdd(conditionalDateNow, 6, "days")))), dateAdd(conditionalDateNow, 6, "days"),
                      includes(weekdays, format(day(dateAdd(conditionalDateNow, 7, "days")))), dateAdd(conditionalDateNow, 7, "days"),
                      false
                    ),
                    ifs(
                      includes(weekdays, format(day(dateAdd(dateDue, 1, "days")))), dateAdd(dateDue, 1, "days"),
                      includes(weekdays, format(day(dateAdd(dateDue, 2, "days")))), dateAdd(dateDue, 2, "days"),
                      includes(weekdays, format(day(dateAdd(dateDue, 3, "days")))), dateAdd(dateDue, 3, "days"),
                      includes(weekdays, format(day(dateAdd(dateDue, 4, "days")))), dateAdd(dateDue, 4, "days"),
                      includes(weekdays, format(day(dateAdd(dateDue, 5, "days")))), dateAdd(dateDue, 5, "days"),
                      includes(weekdays, format(day(dateAdd(dateDue, 6, "days")))), dateAdd(dateDue, 6, "days"),
                      includes(weekdays, format(day(dateAdd(dateDue, 7, "days")))), dateAdd(dateDue, 7, "days")
```
Tokens:
Raw