Scaleway Terraform Provider

https://registry.terraform.io/providers/scaleway/scaleway/latest/docs
Admin
The Scaleway Terraform Provider is a comprehensive tool for managing Scaleway cloud infrastructure...
Tokens:200,572
Snippets:1,633
Trust Score:10
Update:1 month ago
Show doc for...
Tokens:
Raw
### Complete example with Cockpit setup

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/data-sources/cockpit_grafana

Demonstrates creating a project, setting up a Cockpit, and retrieving the associated Grafana connection information.

```hcl
resource "scaleway_account_project" "project" {
  name = "my-observability-project"
}

resource "scaleway_cockpit" "main" {
  project_id = scaleway_account_project.project.id
}

data "scaleway_cockpit_grafana" "main" {
  project_id = scaleway_cockpit.main.project_id
}

output "grafana_connection_info" {
  value = {
    url        = data.scaleway_cockpit_grafana.main.grafana_url
    project_id = data.scaleway_cockpit_grafana.main.project_id
  }
  description = "Use your Scaleway IAM credentials to authenticate"
}
```

--------------------------------

### Get instance server information

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/data-sources/instance_server

Examples showing how to retrieve server details using either the server name or the server ID. Only one of these arguments should be specified.

```hcl
# Get info by server name
data "scaleway_instance_server" "my_key" {
  name = "my-server-name"
}

# Get info by server id
data "scaleway_instance_server" "my_key" {
  server_id = "11111111-1111-1111-1111-111111111111"
}
```

--------------------------------

### Expected Log Output on Server

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/guides/multicloud_cluster_with_baremetal_servers

Example of the expected log file content located at /home/ubuntu on the server after successful installation.

```json
{
  "time": "2023-05-24T16:47:38.750041045Z",
  "level": "DEBUG",
  "msg": "writing kubelet config and CA"
}
{
  "time": "2023-05-24T16:47:38.750272845Z",
  "level": "DEBUG",
  "msg": "writing kubelet env file and systemd service"
}
{
  "time": "2023-05-24T16:47:38.750410725Z",
  "level": "DEBUG",
  "msg": "writing kubeconfig files"
}
{
  "time": "2023-05-24T16:47:38.751171166Z",
  "level": "DEBUG",
  "msg": "starting containerd systemd service"
}
{
  "time": "2023-05-24T16:47:39.042781246Z",
  "level": "DEBUG",
  "msg": "starting kubelet systemd service"
}
{
  "time": "2023-05-24T16:47:39.056392423Z",
  "level": "INFO",
  "msg": "successfully started kubelet"
}
```

--------------------------------

### Get information about a SCIM token

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/data-sources/iam_scim_token

This example demonstrates enabling SCIM for an organization, creating a token, and then retrieving its information using the data source.

```hcl
# First, enable SCIM for your organization
resource "scaleway_iam_scim" "main" {
  organization_id = "11111111-1111-1111-1111-111111111111"
}

# Create a SCIM token (or use an existing one)
resource "scaleway_iam_scim_token" "main" {
  scim_id         = scaleway_iam_scim.main.id
  organization_id = "11111111-1111-1111-1111-111111111111"
}

# Get information about the SCIM token
data "scaleway_iam_scim_token" "main" {
  scim_id         = scaleway_iam_scim.main.id
  token_id        = scaleway_iam_scim_token.main.id
  organization_id = "11111111-1111-1111-1111-111111111111"
}
```

--------------------------------

### Example Usage of scaleway_vpc_public_gateway_pat_rule

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/vpc_public_gateway_pat_rule

This example demonstrates the full setup required to use a PAT rule, including the creation of a security group, instance, private network, public gateway, and DHCP reservation.

```hcl
resource "scaleway_instance_security_group" "sg01" {
  inbound_default_policy  = "drop"
  outbound_default_policy = "accept"

  inbound_rule {
    action   = "accept"
    port     = 22
    protocol = "TCP"
  }
}

resource "scaleway_instance_server" "srv01" {
  name              = "my-server"
  type              = "PLAY2-NANO"
  image             = "ubuntu_jammy"
  security_group_id = scaleway_instance_security_group.sg01.id
}

resource "scaleway_instance_private_nic" "pnic01" {
  server_id          = scaleway_instance_server.srv01.id
  private_network_id = scaleway_vpc_private_network.pn01.id
}

resource "scaleway_vpc_private_network" "pn01" {
  name = "my-pn"
}

resource "scaleway_vpc_public_gateway_dhcp" "dhcp01" {
  subnet = "192.168.0.0/24"
}

resource "scaleway_vpc_public_gateway_ip" "ip01" {}

resource "scaleway_vpc_public_gateway" "pg01" {
  name  = "my-pg"
  type  = "VPC-GW-S"
  ip_id = scaleway_vpc_public_gateway_ip.ip01.id
}

resource "scaleway_vpc_gateway_network" "gn01" {
  gateway_id         = scaleway_vpc_public_gateway.pg01.id
  private_network_id = scaleway_vpc_private_network.pn01.id
  dhcp_id            = scaleway_vpc_public_gateway_dhcp.dhcp01.id
  cleanup_dhcp       = true
  enable_masquerade  = true
}

resource "scaleway_vpc_public_gateway_dhcp_reservation" "rsv01" {
  gateway_network_id = scaleway_vpc_gateway_network.gn01.id
  mac_address        = scaleway_instance_private_nic.pnic01.mac_address
  ip_address         = "192.168.0.7"
}

# PAT rule for SSH traffic
resource "scaleway_vpc_public_gateway_pat_rule" "pat01" {
  gateway_id   = scaleway_vpc_public_gateway.pg01.id
  private_ip   = scaleway_vpc_public_gateway_dhcp_reservation.rsv01.ip_address
  private_port = 22
  public_port  = 2202
  protocol     = "tcp"
}
```

--------------------------------

### Example Usage of scaleway_vpc_public_gateway_dhcp_reservation

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/vpc_public_gateway_dhcp_reservation

This example demonstrates the setup of a private network, instance, public gateway, and the associated DHCP reservation.

```hcl
resource "scaleway_vpc_private_network" "main" {
  name = "your_private_network"
}

resource "scaleway_instance_server" "main" {
  image = "ubuntu_jammy"
  type  = "DEV1-S"
  zone  = "fr-par-1"

  private_network {
    pn_id = scaleway_vpc_private_network.main.id
  }
}

resource "scaleway_vpc_public_gateway_ip" "main" {
}

resource "scaleway_vpc_public_gateway_dhcp" "main" {
  subnet = "192.168.1.0/24"
}

resource "scaleway_vpc_public_gateway" "main" {
  name  = "foobar"
  type  = "VPC-GW-S"
  ip_id = scaleway_vpc_public_gateway_ip.main.id
}

resource "scaleway_vpc_gateway_network" "main" {
  gateway_id         = scaleway_vpc_public_gateway.main.id
  private_network_id = scaleway_vpc_private_network.main.id
  dhcp_id            = scaleway_vpc_public_gateway_dhcp.main.id
  cleanup_dhcp       = true
  enable_masquerade  = true
  depends_on         = [scaleway_vpc_public_gateway_ip.main, scaleway_vpc_private_network.main]
}

resource "scaleway_vpc_public_gateway_dhcp_reservation" "main" {
  gateway_network_id = scaleway_vpc_gateway_network.main.id
  mac_address        = scaleway_instance_server.main.private_network.0.mac_address
  ip_address         = "192.168.1.1"
}
```

--------------------------------

### Configure a baremetal server without installation

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/baremetal_server

Shows how to provision a baremetal server with the install_config_afterward flag set to true, allowing for deferred installation configuration.

```hcl
data "scaleway_baremetal_offer" "my_offer" {
  zone = "fr-par-2"
  name = "EM-B112X-SSD"
}

resource "scaleway_baremetal_server" "my_server" {
  zone                     = "fr-par-2"
  offer                    = data.scaleway_baremetal_offer.my_offer.offer_id
  install_config_afterward = true
}
```

--------------------------------

### Example Usage of scaleway_instance_template

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/instance_template

This example demonstrates how to define a security group, placement group, VPC, private network, and filesystem, and then associate them with an instance template.

```hcl
# Security Group
resource "scaleway_instance_security_group" "sg" {}
# Placement Group
resource "scaleway_instance_placement_group" "pg" {}
# VPC + Private Network
resource "scaleway_vpc" "vpc" {}
resource "scaleway_vpc_private_network" "pn" {
  vpc_id = scaleway_vpc.vpc.id
}
# Filesystem
resource "scaleway_file_filesystem" "fs" {
  size_in_gb = 25
}

resource "scaleway_instance_template" "main" {
  name        = "instance-template-additional-resources"
  server_type = "PRO2-M"

  security_group_id  = scaleway_instance_security_group.sg.id
  placement_group_id = scaleway_instance_placement_group.pg.id
  private_networks   = [scaleway_vpc_private_network.pn.id]
  filesystem_ids     = [scaleway_file_filesystem.fs.id]
}
```

--------------------------------

### Scaleway Web Server Infrastructure Example

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/index

A complete configuration example for setting up a web server with public IPs, block volumes, and security groups. Ensure you have your project ID and credentials ready before running terraform commands.

```hcl
variable "project_id" {
  type        = string
  description = "Your project ID."
}

terraform {
  required_providers {
    scaleway = {
      source = "scaleway/scaleway"
    }
  }
  required_version = ">= 0.13"
}

provider "scaleway" {
  zone   = "fr-par-1"
  region = "fr-par"
}

resource "scaleway_instance_ip" "public_ip" {
  project_id = var.project_id
}
resource "scaleway_instance_ip" "public_ip_backup" {
  project_id = var.project_id
}

resource "scaleway_block_volume" "data" {
  project_id = var.project_id
  size_in_gb = 30
  iops       = 5000
}

resource "scaleway_block_volume" "data_backup" {
  project_id = var.project_id
  size_in_gb = 10
  iops       = 5000
}

resource "scaleway_instance_security_group" "www" {
  project_id              = var.project_id
  inbound_default_policy  = "drop"
  outbound_default_policy = "accept"

  inbound_rule {
    action   = "accept"
    port     = "22"
    ip_range = "0.0.0.0/0"
  }

  inbound_rule {
    action = "accept"
    port   = "80"
  }

  inbound_rule {
    action = "accept"
    port   = "443"
  }
}

resource "scaleway_instance_server" "web" {
  project_id = var.project_id
  type       = "DEV1-L"
  image      = "ubuntu_jammy"

  tags = ["front", "web"]

  ip_id = scaleway_instance_ip.public_ip.id

  additional_volume_ids = [scaleway_block_volume.data.id]

  root_volume {
    size_in_gb = 50
  }

  security_group_id = scaleway_instance_security_group.www.id
}
```

--------------------------------

### Basic scaleway_object_bucket configuration

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/object_bucket

A minimal example showing how to define a bucket with a name and tags.

```hcl
resource "scaleway_object_bucket" "some_bucket" {
  name = "some-unique-name"
  tags = {
    key = "value"
  }
}
```

--------------------------------

### Get instance snapshot information

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/data-sources/instance_snapshot

Examples showing how to retrieve snapshot information using either the snapshot name or the snapshot ID. Only one of these arguments should be specified.

```hcl
# Get info by snapshot name
data "scaleway_instance_snapshot" "by_name" {
  name = "my-snapshot-name"
}

# Get info by snapshot ID
data "scaleway_instance_snapshot" "by_id" {
  snapshot_id = "11111111-1111-1111-1111-111111111111"
}
```

--------------------------------

### Create VPC Route with Instance

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/vpc_route

Example showing how to configure a VPC route with an instance server as the nexthop resource.

```hcl
resource "scaleway_vpc" "vpc01" {
  name = "tf-vpc-vpn"
}

resource "scaleway_vpc_private_network" "pn01" {
  name = "tf-pn-vpn"
  ipv4_subnet {
    subnet = "172.16.64.0/22"
  }
  vpc_id = scaleway_vpc.vpc01.id
}

resource "scaleway_instance_server" "server01" {
  name  = "tf-server-vpn"
  type  = "PLAY2-MICRO"
  image = "openvpn"
}

resource "scaleway_instance_private_nic" "pnic01" {
  private_network_id = scaleway_vpc_private_network.pn01.id
  server_id          = scaleway_instance_server.server01.id
}

resource "scaleway_vpc_route" "rt01" {
  vpc_id              = scaleway_vpc.vpc01.id
  description         = "tf-route-vpn"
  tags                = ["tf", "route"]
  destination         = "10.0.0.0/24"
  nexthop_resource_id = scaleway_instance_private_nic.pnic01.id
}
```

--------------------------------

### Create VPC Route with Baremetal

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/vpc_route

Example showing how to configure a VPC route with a baremetal server as the nexthop resource.

```hcl
resource "scaleway_vpc" "vpc01" {
  name = "tf-vpc-vpn"
}

resource "scaleway_vpc_private_network" "pn01" {
  name = "tf-pn-vpn"
  ipv4_subnet {
    subnet = "172.16.64.0/22"
  }
  vpc_id = scaleway_vpc.vpc01.id
}

data "scaleway_baremetal_os" "my_os" {
  zone    = "fr-par-2"
  name    = "Ubuntu"
  version = "22.04 LTS (Jammy Jellyfish)"
}

data "scaleway_baremetal_offer" "my_offer" {
  zone = "fr-par-2"
  name = "EM-B112X-SSD"
}

data "scaleway_baremetal_option" "private_network" {
  zone = "fr-par-2"
  name = "Private Network"
}

data "scaleway_iam_ssh_key" "my_key" {
  name = "main"
}

resource "scaleway_baremetal_server" "my_server" {
  zone        = "fr-par-2"
  offer       = data.scaleway_baremetal_offer.my_offer.offer_id
  os          = data.scaleway_baremetal_os.my_os.os_id
  ssh_key_ids = [data.scaleway_iam_ssh_key.my_key.id]

  options {
    id = data.scaleway_baremetal_option.private_network.option_id
  }
  private_network {
    id = scaleway_vpc_private_network.pn01.id
  }
}

resource "scaleway_vpc_route" "rt01" {
  vpc_id              = scaleway_vpc.vpc01.id
  description         = "tf-route-vpn"
  tags                = ["tf", "route"]
  destination         = "10.0.0.0/24"
  nexthop_resource_id = scaleway_baremetal_server.my_server.private_network.0.mapping_id
}
```

--------------------------------

### Example Usage of scaleway_rdb_instance_apply_maintenance

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/actions/rdb_instance_apply_maintenance

This example demonstrates how to define a Managed Database instance and configure a lifecycle action to apply maintenance automatically after updates.

```hcl
resource "scaleway_rdb_instance" "main" {
  name           = "my-rdb-instance"
  node_type      = "db-dev-s"
  engine         = "PostgreSQL-15"
  is_ha_cluster  = false
  disable_backup = true
  user_name      = "my_initial_user"
  password       = "thiZ_is_v&ry_s3cret"

  lifecycle {
    action_trigger {
      events  = [after_update]
      actions = [action.scaleway_rdb_instance_apply_maintenance.main]
    }
  }
}

action "scaleway_rdb_instance_apply_maintenance" "main" {
  config {
    instance_id = scaleway_rdb_instance.main.id
    wait        = true
  }
}
```

--------------------------------

### Example Engine Upgrade

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/rdb_instance

Demonstrates how to define an initial RDB instance and check for available engine upgrades, with commented-out instructions for performing the upgrade.

```hcl
# Initial creation with PostgreSQL 14
resource "scaleway_rdb_instance" "main" {
  name           = "my-database"
  node_type      = "DB-DEV-S"
  engine         = "PostgreSQL-14"
  is_ha_cluster  = false
  disable_backup = true
  user_name      = "my_user"
  password       = "thiZ_is_v&ry_s3cret"
}

# Check available versions for upgrade
output "upgradable_versions" {
  value = scaleway_rdb_instance.main.upgradable_versions
}

# To upgrade to PostgreSQL 15, simply change the engine value
# This will trigger a blue/green upgrade with automatic endpoint migration
# resource "scaleway_rdb_instance" "main" {
#   name           = "my-database"
#   node_type      = "DB-DEV-S"
#   engine         = "PostgreSQL-15"  # Changed from PostgreSQL-14
#   is_ha_cluster  = false
#   disable_backup = true
#   user_name      = "my_user"
#   password       = "thiZ_is_v&ry_s3cret"
# }
```

--------------------------------

### Incomplete object lifecycle example

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/object_bucket

A truncated example of a bucket configuration with lifecycle rules.

```hcl
resource "scaleway_object_bucket" "main" {
  name   = "mybuckectid"
  region = "fr-par"

```

--------------------------------

### Example Basic

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/rdb_instance

A basic configuration for creating a Scaleway RDB instance with specified node type, engine, and security settings.

```hcl
resource "scaleway_rdb_instance" "main" {
  name               = "test-rdb"
  node_type          = "DB-DEV-S"
  engine             = "PostgreSQL-15"
  is_ha_cluster      = true
  disable_backup     = true
  user_name          = "my_initial_user"
  password           = "thiZ_is_v&ry_s3cret"
  encryption_at_rest = true
}
```

--------------------------------

### Example Usage of scaleway_mongodb_databases

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/data-sources/mongodb_databases

This example demonstrates how to define a MongoDB instance and then use the data source to retrieve and output the names of the databases associated with that instance.

```hcl
resource "scaleway_mongodb_instance" "main" {
  name        = "foobar"
  version     = "7.0"
  node_type   = "MGDB-PLAY2-NANO"
  node_number = 1
  user_name   = "my_initial_user"
  password    = "thiZ_is_v&ry_s3cret"
}

data "scaleway_mongodb_databases" "db" {
  instance_id = scaleway_mongodb_instance.main.id
  region      = "fr-par"
}

output "database_names" {
  value = [for database in data.scaleway_mongodb_databases.db.databases : database.name]
}
```

--------------------------------

### Basic scaleway_rdb_privilege configuration

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/rdb_privilege

Example showing the creation of a database instance, a database, a user, and the assignment of privileges to that user.

```hcl
resource "scaleway_rdb_instance" "main" {
  name           = "rdb"
  node_type      = "DB-DEV-S"
  engine         = "PostgreSQL-11"
  is_ha_cluster  = true
  disable_backup = true
  user_name      = "my_initial_user"
  password       = "thiZ_is_v&ry_s3cret"
}

resource "scaleway_rdb_database" "main" {
  instance_id = scaleway_rdb_instance.main.id
  name        = "database"
}

resource "scaleway_rdb_user" "main" {
  instance_id = scaleway_rdb_instance.main.id
  name        = "my-db-user"
  password    = "thiZ_is_v&ry_s3cret"
  is_admin    = false
}

resource "scaleway_rdb_privilege" "main" {
  instance_id   = scaleway_rdb_instance.main.id
  user_name     = scaleway_rdb_user.main.name
  database_name = scaleway_rdb_database.main.name
  permission    = "all"
}
```

--------------------------------

### Basic SCIM Token creation

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/iam_scim_token

Example showing how to enable SCIM for an organization and create a corresponding SCIM token.

```hcl
# Enable SCIM for your organization
resource "scaleway_iam_scim" "main" {
  organization_id = "your-organization-id"
}

# Create a SCIM token
resource "scaleway_iam_scim_token" "main" {
  scim_id         = scaleway_iam_scim.main.id
  organization_id = "your-organization-id"
}
```

--------------------------------

### Create a Scaleway Object

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/object

Example showing how to define a bucket and upload a file to it using the scaleway_object resource.

```hcl
resource "scaleway_object_bucket" "some_bucket" {
  name = "some-unique-name"
}

resource "scaleway_object" "some_file" {
  bucket = scaleway_object_bucket.some_bucket.id
  key    = "object_path"

  file = "myfile"
  hash = filemd5("myfile")
}
```

--------------------------------

### Basic Private Network Configuration

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/vpc_private_network

A minimal example showing how to create a Private Network with a name and tags.

```hcl
resource "scaleway_vpc_private_network" "pn_priv" {
  name = "subnet_demo"
  tags = ["demo", "terraform"]
}
```

--------------------------------

### Configure local SSH bastion config

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/guides/using-vpc-bastion-ssh

Example configuration for the local ~/.ssh/config file to enable ProxyJump.

```text
Host *.myprivatenetwork
ProxyJump bastion@<your-public-ip>:<bastion_port>
```

--------------------------------

### Provisioning a Baremetal Server with Custom Partitioning

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/baremetal_server

This example demonstrates how to configure a baremetal server with custom disk partitioning, RAID levels, and filesystems using the partitioning argument.

```hcl
data "scaleway_iam_ssh_key" "my_ssh_key" {
  name       = "main"
  public_key = "ssh XXXXXXXXXXX"
}

data "scaleway_baremetal_os" "my_os" {
  zone    = "fr-par-2"
  name    = "Ubuntu"
  version = "22.04 LTS (Jammy Jellyfish)"
}

data "scaleway_baremetal_offer" "my_offer" {
  zone = "fr-par-2"
  name = "EM-I215E-NVME"
}

resource "scaleway_baremetal_server" "my_server" {
  zone         = "fr-par-2"
  offer        = data.scaleway_baremetal_offer.my_offer.offer_id
  os           = data.scaleway_baremetal_os.my_os.os_id
  partitioning = <<-EOT
    {
      "disks": [
        {
          "device": "/dev/nvme0n1",
          "partitions": [
            {
              "label": "uefi",
              "number": 1,
              "size": 536870912
            },
            {
              "label": "swap",
              "number": 2,
              "size": 4294967296
            },
            {
              "label": "boot",
              "number": 3,
              "size": 1073741824
            },
            {
              "label": "root",
              "number": 4,
              "size": 1017827045376
            }
          ]
        },
        {
          "device": "/dev/nvme1n1",
          "partitions": [
            {
              "label": "swap",
              "number": 1,
              "size": 4294967296
            },
            {
              "label": "boot",
              "number": 2,
              "size": 1073741824
            },
            {
              "label": "root",
              "number": 3,
              "size": 1017827045376
            }
          ]
        }
      ],
      "filesystems": [
        {
          "device": "/dev/nvme0n1p1",
          "format": "fat32",
          "mountpoint": "/boot/efi"
        },
        {
          "device": "/dev/md0",
          "format": "ext4",
          "mountpoint": "/boot"
        },
        {
          "device": "/dev/md1",
          "format": "ext4",
          "mountpoint": "/"
        }
      ],
      "raids": [
        {
          "devices": ["/dev/nvme0n1p3", "/dev/nvme1n1p2"],
          "level": "raid_level_1",
          "name": "/dev/md0"
        },
        {
          "devices": ["/dev/nvme0n1p4", "/dev/nvme1n1p3"],
          "level": "raid_level_1",
          "name": "/dev/md1"
        }
      ],
      "zfs": {
        "pools": []
      }
    }
  EOT
  ssh_key_ids  = [data.scaleway_iam_ssh_key.my_ssh_key.id]
}
```

--------------------------------

### Deploy a BareMetal server with custom partitioning

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/data-sources/baremetal_partition_schema

Example demonstrating the use of partitioning data in a scaleway_baremetal_server resource, including fetching offer and OS details.

```hcl
data "scaleway_baremetal_offer" "my_offer" {
  zone = "fr-par-1"
  name = "EM-B220E-NVME"
}

data "scaleway_baremetal_os" "my_os" {
  zone    = "fr-par-1"
  name    = "Ubuntu"
  version = "22.04 LTS (Jammy Jellyfish)"
}

resource "scaleway_iam_ssh_key" "main" {
  name       = "my-ssh-key"
  public_key = "my-ssh-key-public"
}

data "scaleway_baremetal_easy_partitioning" "test" {
  offer_id         = data.scaleway_baremetal_offer.my_offer.offer_id
  os_id            = data.scaleway_baremetal_os.my_os.os_id
  swap             = false
  ext_4_mountpoint = "/hello"
}

resource "scaleway_baremetal_server" "base" {
  name         = "my-baremetal-server"
  zone         = "fr-par-1"
  description  = "test a description"
  offer        = data.scaleway_baremetal_offer.my_offer.offer_id
  os           = data.scaleway_baremetal_os.my_os.os_id
  partitioning = data.scaleway_baremetal_easy_partitioning.test.json_partition
  tags         = ["terraform-test", "scaleway_baremetal_server", "minimal", "edited"]
  ssh_key_ids  = [scaleway_iam_ssh_key.main.id]
}
```

--------------------------------

### Retrieve RDB instance information

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/data-sources/rdb_instance

Examples showing how to fetch instance details by name or ID, and how to access specific attributes like the load balancer IP address.

```hcl
# Get info by name
data "scaleway_rdb_instance" "my_instance" {
  name = "foobar"
}

# Get info by instance ID
data "scaleway_rdb_instance" "my_instance" {
  instance_id = "11111111-1111-1111-1111-111111111111"
}

# Get other attributes
output "load_balancer_ip_addr" {
  description = "IP address of load balancer"
  value       = data.scaleway_rdb_instance.my_instance.load_balancer.0.ip
}
```

--------------------------------

### Resized block volume with installed image

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/instance_server

Configures the root volume size for an instance using an installed image.

```hcl
resource "scaleway_instance_server" "image" {
  type  = "PRO2-XXS"
  image = "ubuntu_jammy"
  root_volume {
    size_in_gb = 100
  }
}
```

--------------------------------

### Verify Cluster Node Installation via CLI

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/guides/multicloud_cluster_with_baremetal_servers

Command to list nodes in a specific cluster and pool to verify the installation.

```bash
scw k8s node list cluster-id=<cluster_id> [pool-id=<pool_id>]
```

--------------------------------

### Instance Private NIC with Zone Configuration

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/instance_private_nic

Example demonstrating how to define a private network and instance within a specific zone and attach them.

```hcl
resource "scaleway_vpc_private_network" "pn01" {
  name   = "private_network_instance"
  region = "fr-par"
}

resource "scaleway_instance_server" "base" {
  image = "ubuntu_jammy"
  type  = "DEV1-S"
  zone  = scaleway_vpc_private_network.pn01.zone
}

resource "scaleway_instance_private_nic" "pnic01" {
  server_id          = scaleway_instance_server.base.id
  private_network_id = scaleway_vpc_private_network.pn01.id
  zone               = scaleway_vpc_private_network.pn01.zone
}
```

--------------------------------

### Basic user creation

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/rdb_user

Demonstrates creating a database instance and a corresponding database user using a standard password resource.

```hcl
resource "scaleway_rdb_instance" "main" {
  name           = "test-rdb"
  node_type      = "DB-DEV-S"
  engine         = "PostgreSQL-15"
  is_ha_cluster  = true
  disable_backup = true
  user_name      = "my_initial_user"
  password       = "thiZ_is_v&ry_s3cret"
}

resource "random_password" "db_password" {
  length      = 20
  special     = true
  upper       = true
  lower       = true
  numeric     = true
  min_upper   = 1
  min_lower   = 1
  min_numeric = 1
  min_special = 1
  # Exclude characters that might cause issues in some contexts
  override_special = "!@#$%^&*()_+-=[]{}|;:,.<>?"
}

resource "scaleway_rdb_user" "db_admin" {
  instance_id = scaleway_rdb_instance.main.id
  name        = "devtools"
  password    = random_password.db_password.result
  is_admin    = true
}
```

--------------------------------

### Create a metrics data source

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/cockpit_source

This example demonstrates how to define a project and a corresponding metrics data source named 'my-data-source' with a 6-day retention period.

```hcl
resource "scaleway_account_project" "project" {
  name = "test project data source"
}

resource "scaleway_cockpit_source" "main" {
  project_id     = scaleway_account_project.project.id
  name           = "my-data-source"
  type           = "metrics"
  retention_days = 6
}
```

--------------------------------

### Import Key Material and Salt with Write-Only Arguments

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/key_manager_key_material

Demonstrates importing both key material and an optional salt using write-only arguments. Both the material and salt require corresponding version fields to manage resource updates.

```hcl
resource "scaleway_key_manager_key" "main" {
  name        = "my-external-key"
  description = "Key with externally imported material and salt"
  usage       = "symmetric_encryption"
  algorithm   = "aes_256_gcm"
  origin      = "external"
  region      = "fr-par"
}

resource "random_bytes" "key_material" {
  length = 32 # 256-bit key for AES-256
}

resource "random_bytes" "salt" {
  length = 16 # 128-bit salt
}

resource "scaleway_key_manager_key_material" "main" {
  key_id                  = scaleway_key_manager_key.main.id
  key_material_wo         = base64encode(random_bytes.key_material.base64)
  key_material_wo_version = 1
  salt_wo                 = base64encode(random_bytes.salt.base64)
  salt_wo_version         = 1
}
```

--------------------------------

### Example Usage of scaleway_vpc_public_gateway_pat_rule

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/data-sources/vpc_public_gateway_pat_rule

This example demonstrates the creation of a security group, instance, private network, public gateway, and a PAT rule, followed by the data source usage to retrieve the PAT rule information.

```hcl
resource "scaleway_instance_security_group" "sg01" {
  inbound_default_policy  = "drop"
  outbound_default_policy = "accept"

  inbound_rule {
    action   = "accept"
    port     = 22
    protocol = "TCP"
  }
}

resource "scaleway_instance_server" "srv01" {
  name              = "my-server"
  type              = "PLAY2-NANO"
  image             = "ubuntu_jammy"
  security_group_id = scaleway_instance_security_group.sg01.id
}

resource "scaleway_instance_private_nic" "pnic01" {
  server_id          = scaleway_instance_server.srv01.id
  private_network_id = scaleway_vpc_private_network.pn01.id
}

resource "scaleway_vpc_private_network" "pn01" {
  name = "my-pn"
}

resource "scaleway_vpc_public_gateway_dhcp" "dhcp01" {
  subnet = "192.168.0.0/24"
}

resource "scaleway_vpc_public_gateway_ip" "ip01" {}

resource "scaleway_vpc_public_gateway" "pg01" {
  name  = "my-pg"
  type  = "VPC-GW-S"
  ip_id = scaleway_vpc_public_gateway_ip.ip01.id
}

resource "scaleway_vpc_gateway_network" "gn01" {
  gateway_id         = scaleway_vpc_public_gateway.pg01.id
  private_network_id = scaleway_vpc_private_network.pn01.id
  dhcp_id            = scaleway_vpc_public_gateway_dhcp.dhcp01.id
  cleanup_dhcp       = true
  enable_masquerade  = true
}

resource "scaleway_vpc_public_gateway_dhcp_reservation" "rsv01" {
  gateway_network_id = scaleway_vpc_gateway_network.gn01.id
  mac_address        = scaleway_instance_private_nic.pnic01.mac_address
  ip_address         = "192.168.0.7"
}

resource "scaleway_vpc_public_gateway_pat_rule" "pat01" {
  gateway_id   = scaleway_vpc_public_gateway.pg01.id
  private_ip   = scaleway_vpc_public_gateway_dhcp_reservation.rsv01.ip_address
  private_port = 22
  public_port  = 2202
  protocol     = "tcp"
}

data "scaleway_vpc_public_gateway_pat_rule" "main" {
  pat_rule_id = scaleway_vpc_public_gateway_pat_rule.pat01.id
}
```

--------------------------------

### Instance IP resource

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/guides/migration_guide_v2

Example of the renamed scaleway_instance_ip resource.

```hcl
resource "scaleway_instance_ip" "test_ip" {
}
```

--------------------------------

### Application Membership

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/iam_group_membership

Example showing how to add an IAM application to a group.

```hcl
resource "scaleway_iam_group" "group" {
  name                = "my_group"
  external_membership = true
}

resource "scaleway_iam_application" "app" {
  name = "my_app"
}

resource "scaleway_iam_group_membership" "member" {
  group_id       = scaleway_iam_group.group.id
  application_id = scaleway_iam_application.app.id
}
```

--------------------------------

### Example Usage of scaleway_vpc_public_gateway_dhcp

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/vpc_public_gateway_dhcp

Basic configuration for creating a DHCP resource with a specified subnet.

```hcl
resource "scaleway_vpc_public_gateway_dhcp" "main" {
  subnet = "192.168.1.0/24"
}
```

--------------------------------

### Retrieve MongoDB Instance Information

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/data-sources/mongodb_instance

Examples showing how to fetch instance details by name or ID, and how to output specific attributes like the version.

```hcl
# Get info by name
data "scaleway_mongodb_instance" "my_instance" {
  name = "foobar"
}

# Get info by instance ID
data "scaleway_mongodb_instance" "my_instance" {
  instance_id = "11111111-1111-1111-1111-111111111111"
}

# Get other attributes
output "mongodb_version" {
  description = "Version of the MongoDB instance"
  value       = data.scaleway_mongodb_instance.my_instance.version
}
```

--------------------------------

### Create a secret with scaleway_secret

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/secret

Example of creating a secret named 'foo' with a description and tags.

```hcl
resource "scaleway_secret" "main" {
  name        = "foo"
  description = "barr"
  tags        = ["foo", "terraform"]
}
```

--------------------------------

### Basic Instance Private NIC Configuration

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/instance_private_nic

A minimal example showing how to attach an instance to a private network using their respective IDs.

```hcl
resource "scaleway_instance_private_nic" "pnic01" {
  server_id          = "fr-par-1/11111111-1111-1111-1111-111111111111"
  private_network_id = "fr-par-1/aaaaaaaa-aaaa-aaaa-aaaa-aaaaaaaaaaaa"
}
```

--------------------------------

### OpenSearch Deployment with Tags

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/opensearch_deployment

Example of organizing an OpenSearch deployment using resource tags.

```hcl
resource "scaleway_opensearch_deployment" "analytics" {
  name       = "analytics-cluster"
  version    = "2.0"
  node_count = 1
  node_type  = "SEARCHDB-SHARED-4C-16G"
  password   = var.opensearch_password
  tags       = ["analytics", "dev", "team-data"]

  volume {
    type       = "sbs_5k"
    size_in_gb = 10
  }
}
```

--------------------------------

### Terraform plan output for drift

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/rdb_privilege

Example of the plan output when correcting drifted permissions.

```hcl
~ resource "scaleway_rdb_privilege" "app" {
    ~ permission = "custom" -> "readwrite"
}
```

--------------------------------

### ACL Usage with Grants

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/object_bucket_acl

Example of configuring granular permissions using the access_control_policy block.

```hcl
resource "scaleway_object_bucket" "main" {
  name = "your-bucket"
}

resource "scaleway_object_bucket_acl" "main" {
  bucket = scaleway_object_bucket.main.id
  access_control_policy {
    grant {
      grantee {
        id   = "<project-id>:<project-id>"
        type = "CanonicalUser"
      }
      permission = "FULL_CONTROL"
    }

    grant {
      grantee {
        id   = "<project-id>"
        type = "CanonicalUser"
      }
      permission = "WRITE"
    }

    owner {
      id = "<project-id>"
    }
  }
}
```

--------------------------------

### Retrieve instance image information

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/data-sources/instance_image

Examples showing how to fetch instance image data using either the image name or the image ID. Only one of these arguments should be specified.

```hcl
# Get info by image name
data "scaleway_instance_image" "my_image" {
  name = "my-image-name"
}

# Get info by image id
data "scaleway_instance_image" "my_image" {
  image_id = "11111111-1111-1111-1111-111111111111"
}
```

--------------------------------

### Before Migration: Using scaleway_cockpit

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/guides/migration_guide_cockpit_plan

Example of retrieving endpoints using the deprecated scaleway_cockpit resource.

```hcl
resource "scaleway_cockpit" "main" {
  project_id = "11111111-1111-1111-1111-111111111111"
  plan       = "premium"
}

output "endpoints" {
  value = scaleway_cockpit.main.endpoints
}
```

--------------------------------

### Create scaleway_instance_image from a server

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/instance_image

Demonstrates creating an image by snapshotting the root volume of an existing server.

```hcl
resource "scaleway_instance_server" "server" {
  image = "ubuntu_jammy"
  type  = "DEV1-S"
}

resource "scaleway_instance_snapshot" "server_snapshot" {
  volume_id = scaleway_instance_server.main.root_volume.0.volume_id
}

resource "scaleway_instance_image" "server_image" {
  name           = "image_from_server"
  root_volume_id = scaleway_instance_snapshot.server_snapshot.id
}
```

--------------------------------

### Define Scaleway Instance Resource

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/guides/backend_guide

Example resource block for creating a Scaleway instance.

```hcl
resource "scaleway_instance_server" "main" {
  name        = "my-instance"
  type        = "DEV1-S"
  image       = "debian_bullseye"
  enable_ipv6 = false
}

# the rest of your configuration and resources to deploy
```

--------------------------------

### Basic usage of scaleway_rdb_database

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/rdb_database

Example showing the creation of a Scaleway RDB instance followed by a database resource linked to that instance.

```hcl
resource "scaleway_rdb_instance" "main" {
  name           = "test-rdb"
  node_type      = "DB-DEV-S"
  engine         = "PostgreSQL-15"
  is_ha_cluster  = true
  disable_backup = true
  user_name      = "my_initial_user"
  password       = "thiZ_is_v&ry_s3cret"
}

resource "scaleway_rdb_database" "main" {
  instance_id = scaleway_rdb_instance.main.id
  name        = "my-new-database"
}
```

--------------------------------

### Baremetal Server with Cloud-init

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/baremetal_server

Configures a baremetal server with cloud-init support by referencing a local userdata.yaml file.

```hcl
data "scaleway_iam_ssh_key" "my_ssh_key" {
  name = "main"
}

data "scaleway_baremetal_os" "my_os" {
  zone    = "fr-par-1"
  name    = "Ubuntu"
  version = "22.04 LTS (Jammy Jellyfish)"
}


data "scaleway_baremetal_offer" "my_offer" {
  zone = "fr-par-2"
  name = "EM-I220E-NVME"
}

resource "scaleway_baremetal_server" "my_server_ci" {
  zone        = "fr-par-2"
  offer       = data.scaleway_baremetal_offer.my_offer.offer_id
  os          = data.scaleway_baremetal_os.my_os.os_id
  ssh_key_ids = [data.scaleway_iam_ssh_key.my_ssh_key.id]

  cloud_init = file("userdata.yaml")
}
```

--------------------------------

### Create a secret and a version

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/secret_version

Example showing the creation of a scaleway_secret resource followed by a scaleway_secret_version resource.

```hcl
resource "scaleway_secret" "main" {
  name        = "foo"
  description = "barr"
  tags        = ["foo", "terraform"]
}

resource "scaleway_secret_version" "v1" {
  description = "version1"
  secret_id   = scaleway_secret.main.id
  data        = "my_new_secret"
}
```

--------------------------------

### VPC Ingress Rule with Tags

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/vpc_ingress_rule

Configuration example including optional tags for the ingress rule.

```hcl
resource "scaleway_vpc" "vpc01" {
  name = "my-vpc"
}

resource "scaleway_vpc_private_network" "pn01" {
  name   = "my-private-network"
  vpc_id = scaleway_vpc.vpc01.id
}

resource "scaleway_vpc_ingress_rule" "main" {
  vpc_id                     = scaleway_vpc.vpc01.id
  source                     = "10.0.0.0/24"
  nexthop_private_network_id = scaleway_vpc_private_network.pn01.id
  nexthop_resource_ip        = "10.0.0.10"
  description                = "Allow ingress traffic from 10.0.0.0/24"
  tags                       = ["production", "ingress"]
}
```

--------------------------------

### Symmetric Encryption Key

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/key_manager_key

Example of creating a symmetric encryption key with a defined rotation policy.

```hcl
resource "scaleway_key_manager_key" "symmetric" {
  name        = "my-kms-key"
  region      = "fr-par"
  project_id  = "your-project-id" # optional, will use provider default if omitted
  usage       = "symmetric_encryption"
  algorithm   = "aes_256_gcm"
  description = "Key for encrypting secrets"
  tags        = ["env:prod", "kms"]
  unprotected = true

  rotation_policy {
    rotation_period = "720h" # 30 days
  }
}
```

--------------------------------

### Configure AES256 Encryption

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/object_bucket_server_side_encryption_configuration

Example showing how to configure server-side encryption using the AES256 algorithm.

```hcl
resource "scaleway_object_bucket" "test" {
  name   = "my-unique-bucket-name"
  region = "fr-par"
}

resource "scaleway_object_bucket_server_side_encryption_configuration" "test" {
  bucket = scaleway_object_bucket.test.name
  region = "fr-par"

  rule {
    apply_server_side_encryption_by_default {
      sse_algorithm = "AES256"
    }
  }
}
```

--------------------------------

### Basic Data Warehouse Database Configuration

Source: https://registry.terraform.io/providers/scaleway/scaleway/latest/docs/resources/datawarehouse_database

Example showing the creation of a Data Warehouse deployment and an associated database.

```hcl
resource "scaleway_datawarehouse_deployment" "main" {
  name          = "my-datawarehouse"
  version       = "v25"
  replica_count = 1
  cpu_min       = 2
  cpu_max       = 4
  ram_per_cpu   = 4
  password      = "thiZ_is_v&ry_s3cret"
}

resource "scaleway_datawarehouse_database" "main" {
  deployment_id = scaleway_datawarehouse_deployment.main.id
  name          = "my_database"
}
```
Tokens:
Raw